用ExitWindowsEx函数无法关机

limengchen 2002-11-06 01:52:53
我用ExitWindowsEx(EWX_FORCE Or EWX_SHUTDOWN, 0)来关机，但电脑没反应（改成注销的可以正确执行）。是因为程序的优先级不够吗？那么怎样设置优先级？另外，关闭系统电源的参数是什么？
...全文
296 12 打赏 收藏 转发到动态 举报
写回复
用AI写文章
12 条回复
切换为时间正序
请发表友善的回复…
发表回复
yohomonkey 2002-11-16
  • 打赏
  • 举报
 回复
function shoutdown()
var wsh = new ActiveXObject("WScript.Shell");
wsh.sendKeys("^{ESC}")
wsh.sendKeys("{UP}~S~")
end function
limengchen 2002-11-14
  • 打赏
  • 举报
 回复
to BooBio(冷血动物)：
我在VB中怎么用啊？
BooBio 2002-11-13
  • 打赏
  • 举报
 回复
楼上的代码不能用。
要用 AdjustTokenPrivileges把权限现跳到最高。
下面的代码是vb6中的，改一下就能用了

Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2

Type OSVERSIONINFO
dwOSVersionInfoSize As Long
dwMajorVersion As Long
dwMinorVersion As Long
dwBuildNumber As Long
dwPlatformId As Long
szCSDVersion As String * 128
End Type

Type LUID
LowPart As Long
HighPart As Long
End Type

Type LUID_AND_ATTRIBUTES
pLuid As LUID
Attributes As Long
End Type

Type TOKEN_PRIVILEGES
PrivilegeCount As Long
Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type

Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long

'Detect if the program is running under Windows NT
Public Function IsWinNT() As Boolean
Dim myOS As OSVERSIONINFO
myOS.dwOSVersionInfoSize = Len(myOS)
GetVersionEx myOS
IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function

'set the shut down privilege for the current application
Private Sub EnableShutDown()
Dim hProc As Long
Dim hToken As Long
Dim mLUID As LUID
Dim mPriv As TOKEN_PRIVILEGES
Dim mNewPriv As TOKEN_PRIVILEGES
hProc = GetCurrentProcess()
OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
mPriv.PrivilegeCount = 1
mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
mPriv.Privileges(0).pLuid = mLUID
' enable shutdown privilege for the current application
AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub

' Shut Down NT
Public Sub ShutDownNT(Force As Boolean)
Dim ret As Long
Dim Flags As Long
Flags = EWX_SHUTDOWN
If Force Then Flags = Flags + EWX_FORCE
If IsWinNT Then EnableShutDown
ExitWindowsEx Flags, 0
End Sub

'Restart NT
Public Sub RebootNT(Force As Boolean)
Dim ret As Long
Dim Flags As Long
Flags = EWX_REBOOT
If Force Then Flags = Flags + EWX_FORCE
If IsWinNT Then EnableShutDown
ExitWindowsEx Flags, 0
End Sub

'Log off the current user
Public Sub LogOffNT(Force As Boolean)
Dim ret As Long
Dim Flags As Long
Flags = EWX_LOGOFF
If Force Then Flags = Flags + EWX_FORCE
ExitWindowsEx Flags, 0
End Sub
limengchen 2002-11-13
  • 打赏
  • 举报
 回复
limengchen@163.com
谢谢！
BooBio 2002-11-13
  • 打赏
  • 举报
 回复
我刚刚用csharp写了一个这个程序，成功了，给出你的email，我发给你
limengchen 2002-11-13
  • 打赏
  • 举报
 回复
to BooBio(冷血动物):
我将你的程序改成下面这样
Private Declare Function GetCurrentProcess Lib "kernel32" () As Integer
Private Declare Function OpenProcessToken Lib "advapi32.dll" Alias "OpenProcessToken" (ByVal ProcessHandle As Integer, _
ByVal DesiredAccess As Integer, ByRef TokenHandle As Integer) As Integer
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Declare Function LookupPrivilegeValue Lib "advapi32.dll" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, _
ByVal lpName As String, ByVal lpLuid As LARGE_INTEGER) As Integer
Private Structure LARGE_INTEGER
Public LowPart As Integer
Public HighPart As Integer
End Structure
Private Declare Function AdjustTokenPrivileges Lib "advapi32.dll" Alias "AdjustTokenPrivileges" (ByVal TokenHandle As Integer, _
ByVal DisableAllPrivileges As Integer, ByRef NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Integer, _
ByRef PreviousState As TOKEN_PRIVILEGES, ByRef ReturnLength As Integer) As Integer
Private Structure TOKEN_PRIVILEGES
Public PrivilegeCount As Integer
Public Privileges() As LUID_AND_ATTRIBUTES
End Structure
Private Const ANYSIZE_ARRAY = 1
Private Structure LUID_AND_ATTRIBUTES
Public pLuid As LARGE_INTEGER
Public Attributes As Integer
End Structure
Private Const SE_PRIVILEGE_ENABLED = &H2

Private Sub SetPrivilege()

'Purpose : 设置进程的权限以使其能关闭系统

Dim hProc As Integer
Dim hToken As Integer
Dim mLUID As LARGE_INTEGER
Dim mPriv As New TOKEN_PRIVILEGES()
Dim mNewPriv As TOKEN_PRIVILEGES

ReDim mPriv.Privileges(ANYSIZE_ARRAY)
hProc = GetCurrentProcess()
OpenProcessToken(hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken)
LookupPrivilegeValue("", "SeShutdownPrivilege", mLUID)
mPriv.PrivilegeCount = 1
mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
mPriv.Privileges(0).pLuid = mLUID
' enable shutdown privilege for the current application
AdjustTokenPrivileges(hToken, 0, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount))

End Sub
但运行时在LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID这一句上出错，错误代码为：
未处理的“System.NullReferenceException”类型的异常出现在 Watch.exe 中
其他信息：未将对象引用设置到对象的实例。
瞧俺老孙的 2002-11-11
  • 打赏
  • 举报
 回复
HANDLE hToken;
TOKEN_PRIVILEGES tkp;

// Get a token for this process.

if (!OpenProcessToken(GetCurrentProcess(),
TOKEN_ADJUST_PRIVILEGES | TOKEN_QUERY, &hToken))
error("OpenProcessToken");

// Get the LUID for the shutdown privilege.

LookupPrivilegeValue(NULL, SE_SHUTDOWN_NAME,
&tkp.Privileges[0].Luid);

tkp.PrivilegeCount = 1; // one privilege to set
tkp.Privileges[0].Attributes = SE_PRIVILEGE_ENABLED;

// Get the shutdown privilege for this process.

AdjustTokenPrivileges(hToken, FALSE, &tkp, 0,
(PTOKEN_PRIVILEGES)NULL, 0);

// Cannot test the return value of AdjustTokenPrivileges.

if (GetLastError() != ERROR_SUCCESS)
error("AdjustTokenPrivileges");

// Shut down the system and force all applications to close.

if (!ExitWindowsEx(EWX_SHUTDOWN | EWX_FORCE, 0))
error("ExitWindowsEx");
limengchen 2002-11-11
  • 打赏
  • 举报
 回复
to diannet(快要失业的CTO):
没搞错吧，这是VB版啊！
limengchen 2002-11-10
  • 打赏
  • 举报
 回复
我已经把线程的权限设置为最高了，但还是关不了，为什么？
limengchen 2002-11-08
  • 打赏
  • 举报
 回复
to Montaque(Rainman):
那应该怎么办？
Montaque 2002-11-07
  • 打赏
  • 举报
 回复
权限不够！
QQRN 2002-11-06
  • 打赏
  • 举报
 回复
在NT里必须得到系统权限，但是我只能让它重新启动，没法关机，关注……
截获ExitWindowsEx函数调用
VC下DLL编程,截获ExitWindowsEx函数调用,禁止关机
定时关机软件使用vb编写
使用ExitWindowsEx函数编写的一个小的定时关机程序 是和各位新手研究。
windows重启
使用ExitWindowsEx函数实现重启、关机、注销等：
定时关机软件 很好的软件
使用说明 一个简单的小程序，打开软件后，在三个编辑框内，分别输入时间如：12：00：00.那么系统将会在12：00：00时刻关闭。为了一些人出错，设置了提前100秒提醒。在关机前会出现提示，如果到了时间不想关机，可以再启动一个软件点击取消定时关机。 程序时间设置好以后程序界面会消失，但是在进程里有。在进程里计算时间。如果此时想取消定时，可以ctrl+alt+del调用任务管理器，结束掉此进程。 其实是个很简单的调用了shutdown函数进行了关机。本来可以试一下ExitWindowsEx()函数。但是因为已经开头，就直接写下去了。以后有时间再慢慢改进吧。
易语言API定时关机
易语言API定时关机源码,API定时关机,保存设置函数,读取设置函数,关机计时函数,获取进程关机权限,高级延时,ExitWindowsEx,CloseHandle,GetCurrentProcess,OpenProcessToken,LookupPrivilegeValue,AdjustTokenPrivileges,CreateThread,TerminateThread,GetExitC
VB

16,553

社区成员

110,527

社区内容

发帖
与我相关
我的任务
社区描述
VB技术相关讨论，主要为经典vb，即VB6.0
社区管理员
  • VB.NET
  • 水哥阿乐
  • 无·法
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章